Botones Multimedia

Otros de los problemas que se suelen presentar en estas aplicaciones es la implementación de botones con alto contenido gráfico con opciones de rollover, hundido, levantado, desactivado, etc... Todas estas opciones superar las posibilidades del commadbutton y hay que escoger otro sistemas.

Podemos acudir a los controles de Imagen que te permiten poner gráficos y dotarlos de las funcionalidades anteriormente mencionadas.

En un principio estuve trabajando con una clase contenedora y dentro un botón gráfico. La clase contenedora detectaba si el ratón pasaba por ella y le daba tiempo a cambiar el gráfico del botón pero el resultado no era satisfactoria pues si el ratón pasaba demasiado rápido el evento mousemove no se ejecutaba y entonces el botón no cambiaba de forma

Estos controles en combinación con el Timer nos resuelven estos problemas. En un principio era reacion a utizar el Timer pues sobrecarga el procesador y es bastante duro depurar una aplicación con unos cuantos timer activados, pero descubrí que el timer puede estar desactivado (.F.) y sólo activarlo cuando el usuario pasa con el ratón por encima del gráfico con formato de botón que nos interesa activar.

Estos botones a su vez los tenemos de varios tipos:

Tipo1: Las tres posiciones clásicas (normal,rollover,hundido)pero recupera su posición cuando el ratón sale de él.

Tipo2: Las tres posiciones clásicas (normal,rollover,hundido)pero el botón se queda marcado cuando el ratón sale de él.

Tipo3: Las tres posiciones clásicas más la opción de desactivado con lo que tendríamos cuatro opciones.

Pero veamos el código. Unicamente mostraré los Tipo1 y Tipo2 pues el Tipo3 es una variante que se puede controlar, sin problemas, por código:

Pasamos a continuación a la construcción del código que tienes entre los ficheros del mes.

Para poder conseguir todas las funcionalidades deseadas vamos a contruir dos clases. Una clase Timer que se activará cuando el ratón esté por encima y una clase para el gráfico que en principio no hará nada.

Si el uso de las clases siempre es interesante, mucho más en este caso pues los botones que habrá en la aplicación serán numerosos y es especialmente interesante la reutilización de código.

Clase Migráfico

1.- Creamos una clase que vamos a llamar migrafico basada en la clase de Fox Gráficos.

2.- Creamos un método en esa clase llamado onmouseout

Clase MiTimer

1.- Creamos una clase que vamos a llamar Mitimer y que la basamos en la clase Timer de Fox

2.- En el método Timer escribimos el siguiente código:

oToCheck=SYS(1270)
IF TYPE('oToCheck')='O'
	IF !ISNULL(This.ToCheck) AND This.ToCheck.Name <> oToCheck.Name 
		This.ToCheck.OnMouseOut()
		This.ToCheck=.NULL.
		This.Enabled = .F.
	ENDIF	
ELSE
	IF !ISNULL(This.ToCheck)
		This.ToCheck.OnMouseOut()
		This.ToCheck=.NULL.	
	ENDIF
	This.Enabled = .F.
ENDIF	

3.- Creamos un método que vamos a llamar checkforme y escribimos:

LParameters oToCheck

IF TYPE('oToCheck')='O'
	IF !ISNULL(This.ToCheck) 
		IF This.ToCheck.Name <> oToCheck.Name
			This.ToCheck.OnMouseOut()
		ENDIF	
	ENDIF	
	This.ToCheck=oToCheck
	This.Enabled = .T.
ENDIF	

4.- En sus propiedades es especialmente importante poner la propiedad de Enabled a .F. para que no esté disparando continuamente.

5.- La propiedad Interval la reducimos a 50 milisegundos.

6.- Creamos una propiedad que la vamos a llamar Tochek y la rellenamos de momento con un .NULL.

Y ya tenemos casi todo:

Formulario

1.- Creamos un formulario y le ponemos un gráfico basado en nuestra clase Migrafico.

2.- En el método Mousemove escribimos:

This.picture = SET('DEFAULT') + ;
	SYS(2003)+ '\espanoli.bmp'
ThisForm.mitimer1.CheckForMe(This)

3.- En el Método MouseOut escribimos:

this.picture = SET('DEFAULT') +;
 	SYS(2003)+ '\espanold.bmp'

4.- En el Método MouseDown se escribe:

this.picture= SET('DEFAULT') +;
 SYS(2003)+ '\espanol.bmp'

Y ya está.

Para el botón de tipo 2 será necesario usar las mismas clases pero varía ligeramente el código de los métodos:

1.- El método mouseout sería:

IF ! this.picture = SET('DEFAULT') + ;
SYS(2003)+ '\espanol.bmp'
	this.picture = SET('DEFAULT') + ;
SYS(2003)+ '\espanold.bmp'
	thisform.refresh()
ENDIF

2.- El método MouseMove:

IF !This.picture = SET('DEFAULT') + ;
SYS(2003)+ '\espanol.bmp'
	This.picture = SET('DEFAULT') +;
 SYS(2003)+ '\espanoli.bmp'
	ThisForm.mitimer1.CheckForMe(This)
ENDIF
thisform.refresh()

3.- El método MouseDown:

IF this.picture = SET('DEFAULT') + ;
SYS(2003)+ '\espanol.bmp'
	this.picture= SET('DEFAULT') + ;
SYS(2003)+ '\espanold.bmp'
ELSE
	this.picture= SET('DEFAULT') + ;
SYS(2003)+ '\espanol.bmp'
ENDIF